Community discussions

MikroTik App
 
droppedframe
just joined
Topic Author
Posts: 3
Joined: Sat Oct 15, 2022 5:43 pm

RB50009 VLANs

Sat Oct 15, 2022 5:51 pm

Hello,

I am trying to configure an RB5009 with 2 new vlans/subnets. I have created the two vlans following some YouTube guides, but am stuck. From vlan 1, I can ping the router addresses on the new vlan interfaces, but the DHCP server I have configured is not working when I connect on an access port on the new vlans. Also, if I assign a static address to my computer, I cannot ping the gateway or devices in other subnets. Please help!

Here is my config:
/interface bridge
add admin-mac=18:FD:74:78:56:C4 auto-mac=no comment=defconf name=bridge \
    vlan-filtering=yes
/interface vlan
add interface=bridge name=Test vlan-id=100
add interface=bridge name=Data vlan-id=10
/ip pool
add name=default-dhcp ranges=192.168.88.10-192.168.88.254
add name=Data_Pool ranges=192.168.0.101-192.168.0.200
add name=Test_Pool ranges=192.168.100.2
/ip dhcp-server
add address-pool=default-dhcp interface=bridge name=defconf
add address-pool=Data_Pool interface=Data name=Data
add address-pool=Test_Pool interface=Test name=Test
/interface bridge port
add bridge=bridge comment=defconf interface=ether2
add bridge=bridge comment=defconf interface=ether3
add bridge=bridge comment=defconf interface=ether4 pvid=10
add bridge=bridge comment=defconf interface=ether5
add bridge=bridge comment=defconf interface=ether6
add bridge=bridge comment=defconf interface=ether7
add bridge=bridge comment=defconf interface=ether8
add bridge=bridge comment=defconf interface=sfp-sfpplus1
/interface bridge vlan
add bridge=bridge untagged=ether4 vlan-ids=10
add bridge=bridge vlan-ids=100
/ip address
add address=192.168.88.1/24 comment=defconf interface=bridge network=\
    192.168.88.0
add address=192.168.0.1/24 interface=Data network=192.168.0.0
add address=192.168.100.1/30 interface=Test network=192.168.100.0
/ip dhcp-server network
add address=192.168.0.0/24 dns-server=9.9.9.9,149.112.112.112 gateway=\
    192.168.0.1
add address=192.168.88.0/24 comment=defconf dns-server=192.168.88.1 gateway=\
    192.168.88.1
add address=192.168.100.0/30 dns-server=9.9.9.9,149.112.112.112 gateway=\
    192.168.100.1
 
User avatar
anav
Forum Guru
Forum Guru
Posts: 14522
Joined: Sun Feb 18, 2018 11:28 pm
Location: Nova Scotia, Canada
Contact:

Re: RB50009 VLANs

Mon Oct 17, 2022 12:39 am

When your ready not to mix apples and oranges I will return, in other words, have bridge do only bridging and not have it to do DHCP and also vlans with DHCP.
In other words change your bridge subnet to vlan 20 and I will help.
 
tdw
Forum Guru
Forum Guru
Posts: 1556
Joined: Sat May 05, 2018 11:55 am

Re: RB50009 VLANs  [SOLVED]

Mon Oct 17, 2022 1:28 am

You are missing the bridge itself (i.e. the intrinsic bridge-to-CPU port) as a tagged member for the new VLANs, without these there is no connection between the /interface bridge vlan IDs on trunk/access ports and the /interface vlan connected to the bridge. So in this case:
/interface bridge vlan
add bridge=bridge tagged=bridge untagged=ether4 vlan-ids=10
add bridge=bridge tagged=bridge vlan-ids=100


See viewtopic.php?t=173692 for more information. There is nothing actually wrong with using untagged and tagged VLANs on the bridge-to-CPU port, some people just prefer them to be all tagged.
 
droppedframe
just joined
Topic Author
Posts: 3
Joined: Sat Oct 15, 2022 5:43 pm

Re: RB50009 VLANs

Mon Oct 17, 2022 2:58 am

When your ready not to mix apples and oranges I will return, in other words, have bridge do only bridging and not have it to do DHCP and also vlans with DHCP.
In other words change your bridge subnet to vlan 20 and I will help.
Sorry I am confused, I would think a few subnets and DHCP on a router is a fairly standard setup. Maybe there is another way to configure this?
 
droppedframe
just joined
Topic Author
Posts: 3
Joined: Sat Oct 15, 2022 5:43 pm

Re: RB50009 VLANs

Mon Oct 17, 2022 3:06 am

You are missing the bridge itself (i.e. the intrinsic bridge-to-CPU port) as a tagged member for the new VLANs, without these there is no connection between the /interface bridge vlan IDs on trunk/access ports and the /interface vlan connected to the bridge. So in this case:
/interface bridge vlan
add bridge=bridge tagged=bridge untagged=ether4 vlan-ids=10
add bridge=bridge tagged=bridge vlan-ids=100


See viewtopic.php?t=173692 for more information. There is nothing actually wrong with using untagged and tagged VLANs on the bridge-to-CPU port, some people just prefer them to be all tagged.
Interesting, thank you for the suggestion. I have added the bridge as a tagged vlan, but am still unable to receive DHCP from the router. If I configure a static IP on the client, I can ping the gateway, so for some reason, my DHCP config is not handing out an address on the vlan interface.

EDIT:
DHCP started working, just reset the interface. Thank you!

Who is online

Users browsing this forum: anav, Google [Bot], RogerWilco, tdw and 13 guests